How can I sort a list in the text body (bullet points) in pages alphabetically?

Nothing in Pages is based on MS Word and thus, the ability to sort bulleted text or even a list of plain text in Pages is missing from the application.

For sorting a list of words (not a bulleted list) in body text, the free WordService tool from the Mac App Store has a service named Sort Lines Ascending that instantly sorts the words in place. It does not work on a bulleted list though.

For sorting a list of text in body text, or a bulleted list of words, I wrote a macOS Shortcut Service that works on the selected content. It offers the ability to Sort Ascending, Sort Descending, or a simple Reverse order. Looks like this when run:

The Shortcut is written like the following (Note the keyboard shortcut used):

The entire Run AppleScript coding is:

use framework "Foundation"
use AppleScript version "2.4" -- Yosemite or later
use scripting additions

property ca : current application
property listOp : {"Reverse List", "Sort Ascending", "Sort Descending"}

on run {input, parameters}
	set myList to paragraphs of (input as text)
	set ascend to ca's NSSortDescriptor's alloc()'s initWithKey:"" ascending:true
	set descend to ca's NSSortDescriptor's alloc()'s initWithKey:"" ascending:false
	
	set OpSel to (choose from list listOp with title "List Operations" without multiple selections allowed and empty selection allowed)
	if OpSel is false then return
	
	if OpSel contains "Reverse List" then
		set revList to reverse of myList
		return ((ca's NSArray's arrayWithArray:revList)'s componentsJoinedByString:linefeed) as text
	else if OpSel contains "Sort Ascending" then
		set sortedA to (ca's NSArray's arrayWithArray:myList)'s sortedArrayUsingDescriptors:{ascend}
		return (sortedA's componentsJoinedByString:linefeed) as text
	else
		set sortedD to (ca's NSArray's arrayWithArray:myList)'s sortedArrayUsingDescriptors:{descend}
		return (sortedD's componentsJoinedByString:linefeed) as text
	end if
	
	return
end run

This was written and tested on macOS Sequoia v15.3.2 and Pages v14.3.

By clicking this link, you will be prompted to install this Shortcut for use in Pages.

You are welcome.

Apple has chosen to provide a free application (Pages) and free operating system instead of the expensive Microsoft approach. People want Microsoft Word features in Pages yet don't want to pay for it. 😉

Apple is not competing with any word-processing vendor for market share and the free nature of Pages means it won't receive the budget or commitment to be what you want it to be.

You can always let Apple know your thoughts here:

Product Feedback - Apple