Missing 'Sheet' link option in Numbers

Here is a newer script. You can test it out using the Script Editor app. Copy/Paste it to a new document in Script Editor. Select a cell in Numbers that has a cell reference in it as described in the header of the script. Press the Run button in Script Editor.

If it does what you like, you can use Automator to turn it into a Service/Quick Action for application Numbers and it will appear in the Numbers menu under Services. You can assign a keyboard shortcut to it using System Preferences->Keyboard. Alternatively you can use the Shortcuts app to create a shortcut from the script and you can assign a keyboard shortcut to it there, but that has not worked for me in the past.

-- Goto Numbers Cell
-- In a cell in a table will be text of the form sheetname::tablename::rangename
-- such as Sheet 1::Table 1::B2 to go to and select a single cell
-- or Sheet 1::Table 1::B2:D5 to go to and select a range of cells 
-- Select the cell then run the script and the focus should move to the specified cell.
-- Alternatively, the cell may contain sheet and table name without the cell name
-- such as Sheet 1::Table 1
-- In this case the focus will move to cell A1 of the specified table
-- 2024-09-24

tell application "Numbers"
	tell front document
		tell active sheet
			tell (first table whose selection range's class is range)
				set linktext to (value of first cell of (selection range)'s cells as text)
			end tell
		end tell
		
		set myArray to my theSplit(linktext, "::")
		
		set active sheet to sheet (item 1 of myArray)
		tell active sheet to tell table (item 2 of myArray)
			if number of items of myArray = 3 then
				set selection range to range (item 3 of myArray)
			else
				set selection range to range "A1"
			end if
		end tell
		
	end tell
end tell


on theSplit(theString, theDelimiter)
	-- save delimiters to restore old settings
	set oldDelimiters to AppleScript's text item delimiters
	-- set delimiters to delimiter to be used
	set AppleScript's text item delimiters to theDelimiter
	-- create the array
	set theArray to every text item of theString
	-- restore the old setting
	set AppleScript's text item delimiters to oldDelimiters
	-- return the result
	return theArray
end theSplit

You may be running an older version of Numbers that does not have that feature. I don't recall which version it was added. There is an AppleScript way to jump to sheets/tables/cells.

How do I link a Table in Apple Numbers? - Apple Community